Windows 10/11で 何度も復活する英語（米国）USキーボードを削除する方法

問題の説明

Windows 10または11を使用しているとき、システムは時々自動的に米国式キーボードレイアウトを追加することがありますが、設定で該当するオプションを見つけて削除することはできません。

ユーザーが手動で米国式キーボードレイアウトを削除しても、しばらくするとシステムが自動的に再び追加することがあります。このような繰り返しの手動操作は非常に面倒です。

解決策

手動で米国式キーボードレイアウトを繰り返し削除するのを避けるために、自動化された解決方法を見つけました。

バッチファイルの作成

autoRemove-enUS.bat という名前のファイルを作成します。

以下の内容をコピー＆ペーストします：

@ECHO off
chcp 936 >nul
net session >nul 2>&1
if %ERRORLEVEL% neq 0 (
    echo This script requires administrator privileges. Please run as administrator.
    pause
    exit /b
)
(
ECHO ^<gs:GlobalizationServices xmlns:gs="urn:longhornGlobalizationUnattend"^>
ECHO     ^<gs:UserList^>^<gs:User UserID="Current"/^>^</gs:UserList^>
ECHO     ^<gs:InputPreferences^>
ECHO         ^<!-- 米国式キーボード入力を追加 --^>
ECHO         ^<gs:InputLanguageID Action="add" ID="0409:00000409"/^>
ECHO         ^<!-- 米国式キーボード入力を削除 --^>
ECHO         ^<gs:InputLanguageID Action="remove" ID="0409:00000409"/^>
ECHO     ^</gs:InputPreferences^>
ECHO ^</gs:GlobalizationServices^>
) > "%~dp0en-USRemove.xml"
if not exist "%~dp0en-USRemove.xml" (
    echo Error: Failed to create en-USRemove.xml.
    pause
    exit /b
)
CONTROL intl.cpl,, /f:"%~dp0en-USRemove.xml"
del "%~dp0en-USRemove.xml" >nul 2>&1
echo Please check if US keyboard layout is removed.
pause

ファイルを保存して管理者モードで実行します。実行すると、米国式キーボードレイアウトが自動的に削除されます。